home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib16.dsk / SLAVE MAKER.bas < prev    next >
Encoding:
BASIC Source File  |  1990-01-01  |  1.9 KB  |  38 lines
  1. 10  REM  **********************
  2. 20  REM  *    SLAVE  MAKER    *
  3. 30  REM  *  BY  JOEL BUCKLEY  *
  4. 40  REM  * COPYRIGHT (C) 1984 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * LINCOLN, MA. 01773 *
  7. 70  REM  **********************
  8. 100  TEXT : HOME 
  9. 110  PRINT "SLAVE MAKER"
  10. 120  PRINT "---------------------------------------"
  11. 130  PRINT "** COPYRIGHT 1984 BY MICROSPARC, INC. **"
  12. 140  PRINT : PRINT "   THIS PROGRAM WRITES MEMORY RESIDENT"
  13. 150  PRINT : PRINT "DOS TO DISK. (SOMETHING LIKE 'MASTER"
  14. 160  PRINT : PRINT "CREATE' OR 'UPDATE 3.2.1'.)  IT WILL"
  15. 170  PRINT : PRINT "WORK WITH ANY MEMORY SIZE REGULAR,"
  16. 180  PRINT : PRINT "PATCHED, OR EXTENDED DOS 3.2(.1) OR 3.3."
  17. 190 DA =  PEEK(981) *256: REM  $3D2 - DOS BOTTOM
  18. 200 DV =  PEEK(DA +645) + PEEK(DA +8547):DV = (DV = 4) +2 *(DV = 5) +2.1 *(DV = 6) +3 *(DV = 12): REM  $9F85, $BE63  DOS VERSION
  19. 210  PRINT : PRINT "   CURRENT DOS: "(DA +8960)/1024"K DOS 3."DV
  20. 220  IF DV <2  THEN  INVERSE : PRINT : PRINT "THIS VERSION OF DOS NOT SUPPORTED!"; CHR$(7); CHR$(7); CHR$(7): NORMAL : END 
  21. 230  POKE 34, PEEK(37) +1
  22. 240  HOME : PRINT "ENTER GREETING PROGRAM NAME:"
  23. 250  PRINT : INPUT "";F$
  24. 260 F$ =  LEFT$(F$ +"                              ",30): REM  30 SPACES BETWEEN QUOTES
  25. 270  VTAB  PEEK(37): PRINT F$", RIGHT?";
  26. 280  PRINT  CHR$(7);: GET G$: ON G$ = "N" GOTO 240: ON G$ < >"Y" GOTO 280
  27. 290  POKE 34, PEEK(37) +1
  28. 300  HOME : PRINT "INSERT DISK TO BE 'SLAVED', AND THEN"
  29. 310  PRINT : INPUT "PRESS THE <RETURN> KEY. ";G$
  30. 320  POKE DA +3423,0: REM  $AA5F - DOS COMMAND SET TO INIT FOR BOOT
  31. 330  FOR I = 1 TO 30: REM  $AA75-AA92 GREETING PROGRAM NAME 
  32. 340  POKE DA +3444 +I, ASC( MID$ (F$,I)) +128
  33. 350  NEXT I
  34. 360  POKE DA +6891,0: REM  $B7EB - DISK VOLUME NO.
  35. 370  POKE DA +6896,0: POKE DA +6897, PEEK(DA +13): REM  $B7F0-B7F1 DOS BOTTOM FOR INIT (FROM $9D0D) 
  36. 380  CALL DA +6730: REM  $B74A - DOS WRITE ROUTINE (FOR DOS 3.2, 3.2.1, OR 3.3)
  37. 390  HOME : PRINT "DOS HAS BEEN WRITTEN TO DISK."
  38. 400  POKE 34,0